RFYL(By An00b1s)

[FreakyL0L]

//---Авто-Эвент RFYL.---//
//---Скрипт написал aN00B1s (ICQ: 722-45-30)---//

//---Объявление об эвенте.---//

-    script    announce_rfyl    -1,{

//---Время, когда эвент будет начинаться.---//

OnClock1030:
OnClock1530:
OnClock2030:



//---Аннонс Эвента + проверки.---//

announce "Эвент 'Убеги от монстра' начнётся через 3 минуты!",0;
killmonsterall "quiz_01";
sleep 50000;
announce "В Пронтере появился НПС 'Убеги от монстра'!",0;
enablenpc "Убеги от монстра";
sleep 10000;
announce "Эвент 'РФУЛ' начнётся через 2 минуты!",0;
sleep 60000;
announce "Эвент 'РФУЛ' начнётся через 1 минуту!",0;
sleep 30000;
mapannounce "quiz_01","Через 30 секунд будет запущен монстр!",0;
sleep 25000;
announce "Эвент 'РФУЛ' начнётся через -5-",0;
sleep 1000;
announce "Эвент 'РФУЛ' начнётся через -4-",0;
sleep 1000;
announce "Эвент 'РФУЛ' начнётся через -3-",0;
sleep 1000;
announce "Эвент 'РФУЛ' начнётся через -2-",0;
sleep 1000;
announce "Эвент 'РФУЛ' начнется через -1-",0;
sleep 1000;
announce "Эвент 'Убеги от монстра' начался, пусть победит сильнейший!",0,0x00FF00;
monster "quiz_01",42,369,"Убийца",1640,1;
disablenpc "Убеги от монстра";
initnpctimer;
end;

OnTimer5000: // Каждые 5 секунд проверка на количество игроков + аннонс.
if ( getmapusers("quiz_01") == 0 )
{
killmonsterall "quiz_01"; // Если всех убили - эвент заканчивается.
announce "Эвент 'РФУЛ' закончился, так как игроков на Эвенте нет.",0;
disablenpc "Киса";
stopnpctimer;
end;
}
else if ( getmapusers("quiz_01") > 1 )
{
mapannounce "quiz_01",getmapusers("quiz_01") +" игрока(ов) всё ещё находятся на Эвенте.",0,0x00FF00; // Если 2+ игроков на эвенте - аннонс.
initnpctimer;
end;
}
initnpctimer;
end;



//---Выкидывание игрока с Эвента после смерти и проверка на победителя.---//

OnPCDieEvent:
getmapxy .@maprfyl$,.@xrfyl,.@yrfyl,0;
if ( .@maprfyl$ == "quiz_01") {
sleep2 1;
warp "prontera",156,223;
atcommand "@alive "+ strcharinfo(0);
dispbottom "К сожалению, Вы проиграли...";
}
sleep2 1000;
if ( .@maprfyl$ == "quiz_01" && getmapusers("quiz_01") == 1 ) {
killmonsterall "quiz_01";
mapannounce "quiz_01","Поздравляю, Вы выиграли, подойдите пожалуйста к Кисе.",0;
enablenpc "Киса";
stopnpctimer;
end;
}
end;
}



//---Выигрыш.---//

quiz_01,42,369,3    script    Киса    876,{
if (sex == 1) { // Мальчик.
announce "В 'РФУЛе' победил "+ strcharinfo(0) +"! Поздравляем его!",0;
}
else { // Остальные (девочка).
announce "В 'РФУЛе' победила "+ strcharinfo(0) +"! Поздравляем её!",0;
};
getitem 7227,1; // Можно поставить свой приз.
warp "prontera",156,223;
sleep2 250;
disablenpc "Киса";
end;
}



//---Регистрация на Эвент.---//

prontera,147,147,3    script    Убеги от монстра    736,{
mes "[^0000FFУбеги от монстра^000000]";
mes "Вы хотите попасть на Эвент '^FF0000Убеги от монстра^000000'?";
next;
switch(select("Да","Нет")) {
case 1:
if (checkriding()) { // Проверка на Пеко-Пеко.
mes "[^0000FFУбеги от монстра^000000]";
mes "Пожалуйста, снемите Пеко Пеко.";
close;
}
sc_end SC_ALL;
percentheal 100,100;
warp "quiz_01",42,369;
end;
break;

case 2:
mes "[^0000FFУбеги от монстра^000000]";
mes "Хорошо, приходите, когда захотите.";
close;
break;
}
OnInit: // При запуске сервера убераем НПС.
disablenpc "Убеги от монстра";
disablenpc "Киса";
end;
}



//---МапФлаги.---//

quiz_01    mapflag    pvp    off
quiz_01    mapflag    noteleport
quiz_01    mapflag    nosave    SavePoint
quiz_01    mapflag    nowarp
quiz_01    mapflag    noreturn
quiz_01    mapflag    nomemo
quiz_01    mapflag    nowarpto
quiz_01    mapflag    noskill
quiz_01    mapflag    pvp    noparty
quiz_01    mapflag    restricted    5 // Не забывайте добавить зелья, которые нельзя кушать и спид потионы в db/item_noequip.txt

[botka4aet]

...
OnPCDieEvent:
.....
if ( .@maprfyl$ == "quiz_01" && getmapusers("quiz_01") == 1 ) {
killmonsterall "quiz_01";
mapannounce "quiz_01","Поздравляю, Вы выиграли, подойдите пожалуйста к Кисе.",0;
enablenpc "Киса";
...

Если 2 игрока ждут начала эвента и один умирает(@die или DP), то оставшийся выигрывает.

Исправленную версию не прошу - у меня есть версия nomn'а

[Oxxy]

Вот это мозг, добавить 1 мапфлаг так сложно?!

[botka4aet]

Вот это мозг, добавить 1 мапфлаг так сложно?!

Что?

[Oxxy]

Мапфлаг на запрет @команд, если не ошибаюсь такой есть(Извините, в Афине давно не лазил)

[next]

Мапфлаг на запрет @команд, если не ошибаюсь такой есть(Извините, в Афине давно не лазил)

Если дай не включен, то лучше запретить следующие вещи на карте: едп, инка.

[Kubix!]

Мапфлаг на запрет @команд, если не ошибаюсь такой есть(Извините, в Афине давно не лазил)

Если дай не включен, то лучше запретить следующие вещи на карте: едп, инка.

Археолог.