Перейти к содержанию

[Autoevent] mobs

poiuty

Автор poiuty
в Скрипты

 Поделиться

Рекомендуемые сообщения

poiuty Продвинутый пользователь

poiuty

Опубликовано
Опубликовано

Скрипт ~2008 года

5@tower    mapflag    pvp    off
5@tower    mapflag    noicewall
5@tower    mapflag    noloot
5@tower    mapflag    nomemo
5@tower    mapflag    noteleport
5@tower    mapflag    nowarp
5@tower    mapflag    nobranch
5@tower    mapflag    nosave
5@tower    mapflag    nochat
5@tower    mapflag    novending
5@tower    mapflag    nogo
5@tower    mapflag    nodrop

prontera,152,94,6    script    Последний Герой#ELH    781,{
    mes "[Организатор]";
    mes "Привет! Хочешь принять участие";
    mes "в эвенте Последний Герой";
    mes "с супер призом?";
    next;
    mes "[Организатор]";
    mes "Это сражение против огромной";
    mes "массы монстров! Победитель тот,";    // 1201
    mes "кто в итоге останется единственным,"; // 5004
    mes "последним выжывшим в сражении!";
    next;
    mes "[Организатор]";
    if (getmapusers("5@tower") >= $@playcount){
        mes "Извини, участие в эвенте могут принять только "+$@playcount+" игроков.";
        mes "Приходите в другой раз.";
        close;
    }
    mes "Ты хочешь попасть на эвент?";
    next;
    switch (select("Да!","Нет!")){
    case 1:
        percentheal 100,100;
        savepoint "prontera",148,180;
        warp "5@tower",81,83;
        break;
    case 2:
        mes "[Организатор]";
        mes "Надумаете, приходите на следующий эвент.";
        close;
    }
}

5@tower,81,83,5    script    Last Hero MSG::lhmsg    -1,{
OnENStart:
    sleep 20000 * 5;    // 5 Мин на сборы
    disablenpc "Последний Герой#ELH";
    if (getmapusers("5@tower")<($@playcount/5)){
        mapannounce "5@tower","На эвевент не собралось должного количества людей.",bc_map;
        mapannounce "5@tower","Эвент отменяется.",bc_map;
        mapwarp "5@tower","prontera",148,180;
        end;
    }
    mapannounce "5@tower", "Добро пожаловать на эвент последний герой!",bc_map;
    sleep 5000;
    mapannounce "5@tower", "Вы должны противостоять силам зла как можно дольше.",bc_map;
    sleep 5000;
    mapannounce "5@tower", "К сожалению многие из вас погибнут в этой смертельной битве.",bc_map;
    sleep 5000;
    mapannounce "5@tower", "Но лишь один Герой сможет выжить и победить силы зла!",bc_map;
    sleep 5000;
    mapannounce "5@tower", "Удачи вам храбрецы!",bc_map;
    sleep 5000;
    mapannounce "5@tower", "Совсем забыл...Этот герой должен будет сразить Повелителя Зла!",bc_map;
    sleep 5000;
    mapannounce "5@tower","Эвент начнется через минуту.",bc_map;
    sleep 60000;
    mapannounce "5@tower","Монстры атакуют!!!",bc_map;
    set $@vtlLH, 0;
    while(1) {
        for (set .@k,0; .@k<getarraysize($@mobsloopcountLH); set .@k, .@k+1 ) {
            for (set .@i,0; .@i<getarraysize($@mobspawnLH); set .@i, .@i+1 ) {
                set .@indXY, rand(getarraysize($@mobsXspawnLH));
                monster "5@tower",$@mobsXspawnLH[.@indXY],$@mobsYspawnLH[.@indXY],
                    strmobinfo(1,$@mobspawnLH[.@i]),$@mobspawnLH[.@i],$@mobscountLH[.@i]*$@mobsloopcountLH[.@k];
            }
            for (set .@n,0; .@n<120; set .@n, .@n+1 ) {
                if (getmapusers("5@tower") == 1) goto L_LHOne;
                sleep 50;
            }
        }
        if (getmapusers("5@tower") == 1) goto L_LHOne;
        set .@indXY, rand(getarraysize($@mobsXspawnLH));
        monster "5@tower",$@mobsXspawnLH[.@indXY],$@mobsYspawnLH[.@indXY],strmobinfo(1,$@mvpLH),$@mvpLH,1;
        if (!getmapusers("5@tower")) goto L_LHLose;
    }
L_LHOne:
    killmonsterall "5@tower";
    sleep 3000;
    if (!getmapusers("5@tower")) goto L_LHLose;
    mapwarp "5@tower","5@tower",83,83;
    sleep 3000;
    mapannounce "5@tower","А теперь сам повелитель зла!!!!",bc_map;
    mapannounce "5@tower","Одолей теперь ЕГО!!!!.....",bc_map;
    sleep 3000;
    set $@vtlLH, 1;
    monster "5@tower",81,83,"Великий Темный Лорд",1002,1,"lhmsg::OnVTLOnDie";
    initnpctimer "lhmsg";
end;
L_LHLose:
    killmonsterall "5@tower";
    announce "В евенте Последний Герой никто не выстоял!",8;
    mapwarp "5@tower","prontera",148,180;
end;

OnPCDieEvent:
    if (getmapxy(.@mapname$,.@mapx,.@mapy,0,strcharinfo(0)) == 0)
        if (.@mapname$ == "5@tower") {
            sleep2 2000;
            warp "prontera",148,180;
        }
end;

OnVTLOnDie:
    if (!$@vtlLH) end;
    mapannounce "5@tower","Ты выиграл эту БИТВУ!!!",bc_map;
    sleep2 2000;
    mapwarp "5@tower","5@tower",104,103;
    enablenpc "Судья LH";
    initnpctimer "Судья LH";
    stopnpctimer "lhmsg";
end;

OnTimer300000: //5 min
    set $@vtlLH, 0;
    mapannounce "5@tower", "Время на уничтожение Великого Темного Лорда истекло!",bc_map;
    killmonsterall "5@tower";
    mapwarp "5@tower","prontera",148,180;
end;
}

5@tower,108,104,5    script    Судья LH    811,{
    mes "Приветствую победитель!";
    mes "Я вручаю тебе заслуженный приз - "+.@in$+"!";
    next;
    menu "Давай его сюда!",-;
    announce "Победитель битвы Последний Герой - "+strcharinfo(0)+"! Получает приз - 2ТЦг!",8;
    getitem 7227,2;        // !!!! Поставить нужный ИД
    warp "prontera",148,180;
    disablenpc "Судья LH";
end;
OnTimer300000: //5 min
    mapannounce "5@tower", "Время на получение приза истекло!",bc_map;
    mapwarp "5@tower","prontera",148,180;
    disablenpc "Судья LH";
end;
}

// Включение автоэвента.

force_1-3,181,109,5    script    Last Hero    65,{
    if (getgmlevel() > 40) goto gm_menu;
    end;
gm_menu:
    mes "[LH-Event]";
    mes "Гм, что пожелаете?";
    next;
    menu "Включить эвент",menu1,"Выключить эвент",menu2,"Ничего",m_end;
menu1:
    announce "Евент Последний Герой активирован.",8;
    announce "У вас пять минут на регистрацию в Пронтере слева от центральной Кафры!",8;
    enablenpc "Последний Герой#ELH";
    donpcevent "lhmsg::OnENStart";
    close;
menu2:
    disablenpc "Последний Герой#ELH";
    disablenpc "Судья LH";
    if (!$@playcount) set $@playcount, 75;
    cleararray $@mobspawnLH[0],0,getarraysize($@mobspawnLH);
    cleararray $@mobscountLH[0],0,getarraysize($@mobscountLH);
    cleararray $@mobsloopcountLH[0],0,getarraysize($@mobsloopcountLH);
    cleararray $@mobsXspawnLH[0],0,getarraysize($@mobsXspawnLH);
    cleararray $@mobsYspawnLH[0],0,getarraysize($@mobsYspawnLH);
    setarray $@mobspawnLH[0], 1191, 1208, 1374, 1295, 1307, 1302, 1366, 1920, 1921, 1922, 1923, 1924, 1925;
    setarray $@mobscountLH[0], 5,     5,         5,     2,         2,         1,    5,     1,         1,         1, 1,     1,     1;
    setarray $@mobsloopcountLH[0], 1, 2, 4, 8, 16, 32;
    setarray $@mobsXspawnLH[0], 71, 67, 68, 84, 89, 92, 90, 85, 90, 96, 87, 92, 104, 112, 104;
    setarray $@mobsYspawnLH[0], 69, 84, 95, 91, 84, 77, 71, 97, 97, 99, 107, 108, 104, 89, 93;
    set $@mvpLH, 1251;    
    mes "[LH-Event]";
    mes "Эвент деактивирован";
    close;
m_end:
    mes "[LH-Event]";
    mes "Как скажете Гм,я всегда к вашим услугам.";
    close;
}

// Авто включение эвента.

-    script    EvLH    -1,{
end;
OnClock1200:
OnClock1600:
OnClock2000:
OnClock2300:
    enablenpc "Последний Герой#ELH";
    donpcevent "lhmsg::OnENStart";
end;
OnInit:
    disablenpc "Судья LH";
    disablenpc "Последний Герой#ELH";
    setarray $@mobspawnLH[0], 1191, 1208, 1374, 1295, 1307, 1302, 1366, 1920, 1921, 1922, 1923, 1924, 1925;
    setarray $@mobscountLH[0], 5,     5,         5,     2,         2,         1,    5,     1,         1,         1, 1,     1,     1;
    setarray $@mobsloopcountLH[0], 1, 2, 4, 8, 16, 32;
    setarray $@mobsXspawnLH[0], 71, 67, 68, 84, 89, 92, 90, 85, 90, 96, 87, 92, 104, 112, 104;
    setarray $@mobsYspawnLH[0], 69, 84, 95, 91, 84, 77, 71, 97, 97, 99, 107, 108, 104, 89, 93;
    set $@mvpLH, 1251;
    set $@playcount, 9;
end;
}

Ссылка на комментарий
Поделиться на другие сайты
 Поделиться
Перейти к списку тем
×
×
  • Создать...
Яндекс.Метрика