скрипт анти бота

[Gavard]

вот сам скрипт

//===== Thaddeus Scripts ==================================
//= Simple Cool Anti-Bot
//===== By: ==================================================
//= Thaddeus
//===== Current Version: =====================================
//= 1.0
//===== Compatible With: =====================================
//= Hercules, rAthena, 3ceam, eAthena
//===== Description: =========================================
// Improvise Simple Anti-Bot! from method of Brian.
//===== Comments: ============================================
//= Change the % chance of triggering, change jail time.
//===== Additional Comments: =================================
//= 1.00 Initial Release
//===== Contact Info: =========================================
//= http://hercules.ws/board/user/457-thaddeus/
//============================================================
//===== Credits to: =========================================
//= Brian,
//============================================================


- script anti-bot2 -1,{
OnPCLoginEvent:
set checkbot,0;
if(botter >= 1) {
doevent "anti-bot::Oncheckb"; }

}
- script anti-bot -1,{
OnNPCKillEvent:
if( rand(100) < 75 ) {goto end;} // Default Setting: 75% Chance to Ignore the Anti-Bot
Oncheckb:
function GetString;
//if (getgmlevel() >= 3) { goto end;} /* Uncomment if you want to Ignore this by GM */
if(checkbot >= 1) { goto end; }

atcommand "@jail "+strcharinfo(0)+"";
set botter,1;
sleep2 3000;
On2nd:
set .@String$,GetString( 15,rand(3,7) );
mes "Здравствуйте";
mes "У нас возникло подозрение что вы БОТ";
mes "Вы назодитесь в Тюрьме";
mes "Вы можете избежать наказания !";
mes "Введите, только то, что выделено ^FF0000Красным Цветом:^000000";
mes "Будте внимательнее !";
mes "^0000FF"+GetString( 15,rand(5,10) )+"^FF0000"+.@String$+"^0000FF"+GetString( 15,rand(3,10) )+"^000000";
input .@Input$;
if( .@Input$ != .@String$ ){
if (botter >= 3)
{
atcommand "@unjail "+strcharinfo(0)+"";
sleep2 1000;
atcommand "@jailfor 10d "+strcharinfo(0)+"";
announce "[Anti-BOT]: Игрок [" +strcharinfo(0) +"] был пойман в Ботоводтве, Джайл 10 дней.",0,0xe80f0f;

set botter,0;
close;
end;}

mes "Проверка...";
set botter,botter + 1;
next;
goto On2nd;
}
atcommand "@unjail "+strcharinfo(0)+"";
set botter,0;
set checkbot,1;
end;

function GetString {
if( getarg(0) & 1 ) setarray .@List$[ getarraysize( .@List$ ) ],"1","2","3","4","5","6","7","8","9";
if( getarg(0) & 2 ) setarray .@List$[ getarraysize( .@List$ ) ],"A","B","C","D","E","F","G","H","J","K","L","M","N","O","P","Q","R","S","T","U","V","W","X","Y","Z";
if( getarg(0) & 4 ) setarray .@List$[ getarraysize( .@List$ ) ],"a","b","c","d","e","f","g","h","i","j","k","m","n","o","p","q","r","s","t","u","v","w","x","y","z";
//if( getarg(0) & 8 ) setarray .@List$[ getarraysize( .@List$ ) ],"!","@","#","$","%","^","&","*","(",")","-","=","/","+";

set .@Str$,"";
while( getstrlen( .@Str$ ) < getarg(1) )
set .@Str$,.@Str$ + .@List$[ rand( getarraysize( .@List$ ) ) ];
return .@Str$;

}

}

sec_pri mapflag pvp off

взял скрипт ТУТ

хотелось бы чтобы данный анти-бот делал проверку за убийство каждого 300го моба

помогите пожалуйста, а то я почти не шарю в этом)

[Extez1]

Примерно так

OnNPCKillEvent:
set @mob_killed, @mob_killed+1;
if(@mob_killed < 300) end;
else { doevent "anti-bot::Oncheckb"; }

Oncheckb:
@mob_killed надо обнулить.

Изменено 22 февраля, 2015 пользователем Extez1

[hakilo]

Ага и тебя пошлют после 2 часов игры в патьке где бегают и убивают мобов пачками )))

[Extez1]

Ага и тебя пошлют после 2 часов игры в патьке где бегают и убивают мобов пачками )))

Каждые 300, не так напряжно. Тут больше проблема, что бы на эвенте не выскакивало.

Изменено 23 февраля, 2015 пользователем Extez1

[Gavard]

Примерно так

OnNPCKillEvent:
set @mob_killed, @mob_killed+1;
if(@mob_killed < 300) end;
else { doevent "anti-bot::Oncheckb"; }

Oncheckb:
@mob_killed надо обнулить.

ошибок в сервере нету, но и не работает, так как рекольнуло при убийстве 46 моба

[Extez1]

blablabla

Х_Х 30 стоит пробуй.

- script anti-bot -1,{
OnNPCKillEvent:
set mob_killed, mob_killed+1;
if(mob_killed => 30) { goto Oncheckb; }
else{ goto end;}
Oncheckb:
function GetString;
if(checkbot >= 1) { goto end; }
atcommand "@jail "+strcharinfo(0)+"";
set botter,1;
set mob_killed,0;
sleep2 3000;

Изменено 23 февраля, 2015 пользователем Extez1

[Nurkz]

Правильное название скрипта "Анти-Онлайн"

-    script    anti-bot2    -1,{

    OnPCLoginEvent:

        set checkbot, 0;
        if( botter >= 1 )
            doevent "anti-bot::Oncheckb";

}


-    script    anti-bot    -1,{

    OnNPCKillEvent:
    set mob, mob +1;
    if( mob < 300 ) end;

    Oncheckb:

        function GetString;
        //if (getgmlevel() >= 3) { goto end;} /* Uncomment if you want to Ignore this by GM */
        if( checkbot >= 1 ) end;

        atcommand "@jail "+strcharinfo(0)+"";
        set botter, 1;
        set mob, 0;
        sleep2 3000;

    On2nd:

        set .@String$,GetString( 15,rand(3,7) );
        mes "Здравствуйте";
        mes "У нас возникло подозрение что вы БОТ";
        mes "Вы назодитесь в Тюрьме";
        mes "Вы можете избежать наказания !";
        mes "Введите, только то, что выделено ^FF0000Красным Цветом:^000000";
        mes "Будте внимательнее !";
        mes "^0000FF"+GetString( 15,rand(5,10) )+"^FF0000"+.@String$+"^0000FF"+GetString( 15,rand(3,10) )+"^000000";
        input .@Input$;
        if( .@Input$ != .@String$ )
        {
            if (botter >= 3)
            {
                atcommand "@unjail "+strcharinfo(0)+"";
                sleep2 1000;
                atcommand "@jailfor 10d "+strcharinfo(0)+"";
                announce "[Anti-BOT]: Игрок [" +strcharinfo(0) +"] был пойман в Ботоводтве, Джайл 10 дней.",0,0xe80f0f;

                set botter,0;
                close;
            }

            mes "Проверка...";
            set botter, botter +1;
            next;
            goto On2nd;
        }

        atcommand "@unjail "+strcharinfo(0)+"";
        set botter,0;
        set checkbot,1;
        end;

    function    GetString    {

        if( getarg(0) & 1 ) setarray .@List$[ getarraysize( .@List$ ) ],"1","2","3","4","5","6","7","8","9";
        if( getarg(0) & 2 ) setarray .@List$[ getarraysize( .@List$ ) ],"A","B","C","D","E","F","G","H","J","K","L","M","N","O","P","Q","R","S","T","U","V","W","X","Y","Z";
        if( getarg(0) & 4 ) setarray .@List$[ getarraysize( .@List$ ) ],"a","b","c","d","e","f","g","h","i","j","k","m","n","o","p","q","r","s","t","u","v","w","x","y","z";
        //if( getarg(0) & 8 ) setarray .@List$[ getarraysize( .@List$ ) ],"!","@","#","$","%","^","&","*","(",")","-","=","/","+";

        set .@Str$,"";
        while( getstrlen( .@Str$ ) < getarg(1) )
        set .@Str$,.@Str$ + .@List$[ rand( getarraysize( .@List$ ) ) ];
        return .@Str$;

    }

}

sec_pri    mapflag    pvp off

[ggRo]

а можно сделать на определенный класс? (Хим Крео)

[Clown]

а можно сделать на определенный класс? (Хим Крео)

Проверку на профессию

[ggRo]

а можно сделать на определенный класс? (Хим Крео)

Проверку на профессию

да, забыл слово)) пришлось класс написать))